デバッグ時にバッチファイルで固定IPとDHCPを切り替える

@echo off
set /P INP="固定IP(f)、DHCP(d)のどちらにしますか？（ f or d ）"

rem 最近のOSではこうなっている場合が多いです.
set NETNAME="イーサネット"

rem 昔のOSではこういう文字列でした.
rem set NETNAME="ローカル エリア接続"

rem これはユーザ定義の成功文字列
set SUC=設定変更に成功しました.

rem これはユーザ定義のエラーメッセージ文字列.
set ERR=エラー、f または d 以外は受け付けません.

rem -------------------------------------------------------------------

if /i %INP%==d goto LABEL_DHCP
if /i %INP%==f goto LABEL_FIX

echo you push %INP%
echo %ERR%
pause
exit

rem -------------------------------------------------------------------
:LABEL_DHCP

netsh interface ip set address name=%NETNAME% source=dhcp

echo you push %INP%
echo %SUC%
pause
exit

rem -------------------------------------------------------------------
:LABEL_FIX

rem 下記をネット環境に応じて変更する.
set IP_ADDRESS="192.168.0.30"

rem 下記をネット環境に応じて変更する.
set MASK="255.255.255.0"

rem 下記をネット環境に応じて変更する.
set GW_ADDRESS="192.168.0.254"

rem 下記をネット環境に応じて変更する.
set DNS_ADDRESS="192.168.0.30"

rem アイピーアドレスを設定する.
netsh interface ip set address name=%NETNAME% source=static addr=%IP_ADDRESS% mask=%MASK% gateway=%GW_ADDRESS%

rem ドメインネームサーバアドレスを設定する(アドレスが適切でない場合は時間がかかるが設定自体はできる).
rem パソコンとパソコンの1:1のローカルLAN通信の場合は設定する必要なし.
netsh interface ip set dnsserver name=%NETNAME% source=static addr=%DNS_ADDRESS%

echo you push %INP%
echo %SUC%
pause
exit

rem -------------------------------------------------------------------

ipconfig

ipconfig /all